# Pentachronos

Berechnungsregel für zeitliche Gültigkeiten

Die bisherigen Regeln zur [Berechnung der zeitlichen Gültigkeit](file:///C:\pages\viewpage.action%3fpageId=18186789) erlauben zwar für übliche Standardanwendungsfälle eine einfache Angabe der Gültigkeitsregel, jedoch sind dabei alle Berechnungsvarianten im Code des Tarifmoduls hinterlegt und Erweiterungen bei Spezialfällen haben stets eine Codeerweiterung beim Tarifmodul zur Folge.

Im Folgenden ist daher ein Regelwerk beschrieben, welches die Darstellung/Berechnung vielfältigster Varianten der zeitlichen Gültigkeit ermöglicht. Innerhalb des Husst-fähigen Vertriebsgerätes ist nur einmalig das Regelwerk zu implementieren. Die damit bereitgestellten Berechnungswerkzeuge erlauben dann nicht nur die Berechnung von zeitlichen Gültigkeiten, wie sie für den Fahrscheindruck oder die Ablage von Gültigkeitsbeginn und Gültigkeitsende auf elektronischen Medien bzw. bei der Registrierung eines Fahrscheinverkaufs benötigt werden, sondern auch die Prüfung der Gültigkeit eines Fahrscheins im Rahmen einer Kontrolle.

Wie bei den bisherigen Regeln erfolgt die Angabe zur Berechnung über die Sorten bzw. Preise Attribute GueltigRegel und GueltigParam. Das Attribut GueltigText wird nicht mehr verwendet:

|  |  |  |
| --- | --- | --- |
| **GueltigRegel** | **GueltigParam** | **GueltigText** |
| 5 | (Berechnungsregeln) | entfällt |

## Beschreibung der Berechnungsregeln

### Grundgedanken

Die Berechnungsregeln erlauben aufgrund des aktuellen Zeitpunktes die

* Bestimmung von zeitlichem Gültigkeitsbeginn/-ende einer auszugebenden Fahrtberechtigung,
* Bestimmung von zeitlichem Gültigkeitsbeginn/-ende für die Rückfahrt bei einer auszugebenden Fahrtberechtigung sowie
* spezifische Prüfung der zeitlichen Gültigkeit im Rahmen der Kontrolle einer Fahrtberechtigung.

Bei der Bestimmung von zeitlichem Gültigkeitsbeginn bzw. Gültigkeitsende kann sowohl

* der jeweilige tatsächliche Zeitpunkt,
* der für den Fahrscheindruck zu verwendende Zeitpunkt sowie
* ein für den Fahrscheindruck alternativ zu verwendender Gültigkeitstext

bestimmt werden.

Jede Berechnungsregel ist eine Abfolge von Aktionen, die ggf. nur aufgrund optionaler Bedingungen ausgeführt werden.

Die Aktionen ändern die Zeitpunkte (oder setzen Gültigkeitstexte), wobei die Änderung sich aufgrund des Wertes auch nur auf Teilelemente eines Zeitpunktes (z.B. nur den Monat) beziehen können.

Bei der Syntax der Berechnungsregeln lag das Augenmerk primär auf einer einfachen Implementierungsmöglichkeit.

### Formale Beschreibung (EBNF) – V1.0

Regeln = Regel , { Regeln } ;

Regel = Regeltyp "[" Regelbeschreibung , "]" ;

Regeltyp = "Dauer" | "DauerRueckfahrt" | "Gueltig" ;

Regelbeschreibung = BedingteRegeln , { ";" , BedingteRegeln } ;

BedingteRegeln = BedingteRegel , { "|" , BedingteRegel } ;

BegingteRegel = WiederholteBedingteRegel | EinmalBedingteRegel | UnbedingteRegel ;

WiederholteBedingteRegel = "\*" , Bedingungen, ":", Aktionen ;

EinmalBedingteRegel = "?", Bedingungen, ":", Aktionen ;

UnbedingteRegel = Aktionen ;

Bedingungen = Bedingung , { "," , Bedingung } ;

Bedingung = Einzelbedingung { "&" Einzelbedingung } ;

Einzelbedingung = Variable , Vergleich , Vergleichswert ;

Vergleich = "==" | "!=" | ">" | "<" | ">=" | "<=" ;

Vergleichswert = "OK" | NumerischerWert ;

Aktionen = Aktion, { "," , Aktion } ;

Aktion = Endeaktion | Modifikationsaktion ;

Endeaktion = "GUELTIG" | "UNGUELTIG" ;

Modifikationsaktion = Variable , Zuweisungsoperator , Wert ;

Zuweisungsoperator = "=" | "+=" | "-=" ;

Variable = Bezeichner , { "." , Bezeichner } ;

Bezeichner = Buchstabe , { Buchstabe } ;

Buchstabe = "A" | "B" | "C" | "D" | "E" | "F" | "G"

| "H" | "I" | "J" | "K" | "L" | "M" | "N"

| "O" | "P" | "Q" | "R" | "S" | "T" | "U"

| "V" | "W" | "X" | "Y" | "Z" ;

Wert = NumerischerWert | Textkonstante ;

NumerischerWert = Variable | Konstante ;

Textkonstante = '"' , Zeichenkette, '"' ;

Zeichenkette = { AlleZeichen - '"' } ;

AlleZeichen = ? alle druckbaren Zeichen ? ;

Konstante = ZahlMitEinheit , { ZahlMitEinheit } ;

ZahlMitEinheit = Zahl , Einheit ;

Zahl = Sonderwert | Ganzzahl ;

Sonderwert = "MAX" ;

Ganzzahl = Ziffer , { Ziffer } ;

Ziffer = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9" ;

Einheit = "TAG" | "MON" | "JAHR" | "STD" | "MIN" | "SEK" | "WOCHENTAG" | "TAGESART" ;

#### Regeltyp

|  |  |
| --- | --- |
| **Regeltyp** | **Beschreibung** |
| Dauer | Berechnung der zeitlichen Gültigkeit für die Ausgabe einer Fahrtberechtigung |
| DauerRueckfahrt | Berechnung der zeitlichen Gültigkeit der Rückfahrt im Rahmen der Ausgabe einer Fahrtberechtigung |
| Gueltig | Prüfung, ob die Fahrtberechtigung zum aktuellen Zeitpunkt gültig ist |

#### Zuweisungsoperatoren

|  |  |
| --- | --- |
| **Zuweisungsoperator** | **Bedeutung** |
| = | Zuweisung |
| += | Erhöhung um den angegebenen Wert |
| -= | Erniedrigung um den angegebenen Wert |

#### Endeaktionen

|  |  |
| --- | --- |
| **Endeaktion** | **Beschreibung** |
| GUELTIG | Das Ergebnis der Berechnung ist gültig (die Fahrtberechtigung ist derzeit im Rahmen der Kontrolle gültig bzw. es konnte eine zeitliche Gültigkeit bestimmt werden) |
| UNGUELTIG | Das Ergebnis der Berechnung ist ungültig (die Fahrtberechtigung ist derzeit im Rahmen der Kontrolle ungültig bzw. es konnte keine zeitliche Gültigkeit bestimmt werden) |

#### Sonderwerte

|  |  |
| --- | --- |
| **Sonderwert** | **Bedeutung** |
| MAX | Größtmöglicher Wert unter Berücksichtigung der höheren Werte (z.B. MAX TAG für den letzten Tag im jeweiligen Monat) |

#### Weitere Hinweise

Leerzeichen dürfen (analog zu anderen üblichen Programmiersprachen) bei Bedarf zwischen Terminalsymbole eingefügt werden.

Wurden Aktionen innerhalb von BedingteRegel ausgeführt, so wird kein weiteres Objekt BedingteRegel innerhalb der gleichen BedingtenRegeln ausgeführt, d.h. die einzelnen BedingteRegel wirken wie eine IF-ELSEIF-...-ELSE-Gruppe.

Mehrere Bedingungen in Bedingungen werden Oder-verknüpft, d.h. Bedingungen ist erfüllt, wenn eine Bedingung erfüllt ist.

Mehrere Einzelbedingungen in Bedingung werden Und-Verknüpft, d.h. Bedingung ist erfüllt, wenn jede Einzelbedingung erfüllt ist.

Bei partieller Änderung eines Zeitpunktes mit Über-/Unterschreitung des jeweiligen Minimal-/Maximalwertes eines Teilelements wird automatisch ein "Wrapping" durchgeführt und hierarchisch höhere Teileelemente entsprechend angepasst.

Beispiel: Bei einem im Dezember liegenden Zeitpunkt, bei dem der Monat um den Wert eins erhöht wird, würde der Monat auf Januar gesetzt und das Jahr um eins erhöht werden.

Da hierarchisch niedrigere Teilelemente (auf das Beispiel bezogen: Tag, Stunde, Minute und Sekunde) nicht berücksichtigt werden, können temporär auch nicht existente Zeitpunkte (z.B. der **31**.02.2020) entstehen (beispielsweise, wenn beim Zeitpunkt 31.01.2020 der Monat um den Wert eins erhöht würde).

Die Prüfung, ob ein temporär bestimmter Zeitpunkt zulässig ist, kann durch Vergleich des Zeitpunktes mit dem Wert OK erfolgen.

Beim Start jeder Berechnungsregel gilt:

* Alle numerischen Werte für den zeitlichen Gültigkeitsbeginn sind auf den aktuellen Zeitpunkt gesetzt (kurz: VON=AKTUELL).
* Alle numerischen Werte für das zeitliche Gültigkeitsende sind auf den aktuellen Zeitpunkt gesetzt (kurz: BIS=AKTUELL).
* Alle Texte für Gültigkeitsbeginn oder -ende sind nicht gesetzt.

Beim Ende jeder Berechnungsregel gilt:

* Liegt ein Wert eines Zeitpunktes außerhalb des gültigen Bereichs, so wird er auf den jeweiligen Minimal- bzw. Maximalwert gesetzt, d.h. ein (ungültiges) Datum 30.02.2020 würde auf 29.02.2020 korrigiert werden.

Das logische Ergebnis der Gültigkeitsberechnung ist der Wert der angegebenen Endeaktion. Wenn keine Endeaktion angegeben wurde, ist das Ergebnis GUELTIG.

### Variablen

An Variablen stehen derzeit die folgenden Basisobjekte zur Verfügung:

|  |  |
| --- | --- |
| **Objekt** | **Beschreibung** |
| AKTUELL | aktueller Zeitpunkt |
| VON | zeitlicher Gültigkeitsbeginn |
| BIS | zeitliches Gültigkeitsende |
| TEXT | allgemeiner Gültigkeitstext |
| PARAM | applikationsseitige zeitliche optionale Gültigkeitsparameter (z.B. für Zeitkarten mit variabler Gültigkeitszeit) |

Die Basisobjekte VON und BIS bestehen aus den folgenden Unterobjekten:

|  |  |
| --- | --- |
| **Unterobjekt** | **Beschreibung** |
| GUELTIG | tatsächlicher Zeitpunkt (Zeitpunkt, der für die automatische zeitliche Gültigkeitsprüfung verwendet wird) |
| DRUCK | für den Druck zu verwendender Zeitpunkt |
| TEXT | für den Druck zu verwendender Text |

#### Einheiten

Die Einheiten sind in hierarchisch absteigender Reihenfolge angegeben.

|  |  |
| --- | --- |
| **Einheit** | **Beschreibung** |
| JAHR | Jahr |
| MON | Monat als numerischer Wert (1 = Januar, 2 = Februar, ..., 12 = Dezember) |
| TAG | Tag im Monat |
| STD | Stunde |
| MIN | Minute |
| SEK | Sekunde |
| WOCHENTAG | Wochentag als numerischer Wert (1 = Montag, 2 = Dienstag, ..., 7 = Sonntag) |
| TAGESART | Tagesart als numerischer Wert, der sich aus dem Datum anhand der in der Tariftransportdatenbank enthaltenen Tagesarten-/Betriebstagstabelle ergibt (0 = dem Datum ist keine Tagesart zugeordnet) |

#### Weitere Hinweise

* Eine Änderung eines Basisobjekts ändert auch alle Unterobjekte, d.h. VON=... ist identisch mit VON.GUELTIG=...,VON.DRUCK=....
* Für die Einheiten WOCHENTAG und TAGESART sind keine über-/untergeordneten Einheiten definiert.
* Die Einheiten WOCHENTAG und TAGESART dürfen nur im Rahmen von Bedingungen, aber nicht von Aktionen verwendet werden, d.h. das Setzen oder Änderung des Wochentags bzw. der Tagesart ist nicht zulässig.
* Bei Vergleichen werden nur die jeweils angegebenen Einheiten geprüft, d.h. ein Vergleich AKTUELL > 4 MON 12 TAG prüft, ob unabhängig von Jahr und Uhrzeit das Datum größer als der 12.4. ist.
* Wochentag und Tagesart werden bei Änderungen des Datums, sofern dieses ein gültiges Datum darstellt, automatisch berechnet.

## Beispiele

|  |  |
| --- | --- |
| **Beschreibung** | **GueltigParam** |
| Kalendermonatskarte | Dauer[VON = 1 TAG 0 STD 0 MIN 0 SEK, BIS = MAX TAG 23 STD 59 MIN 59 SEK] |
| Kalenderwochenkarte | Dauer[\* VON != 1 WOCHENTAG: VON -= 1 TAG; \* BIS != 7 WOCHENTAG: BIS += 1 TAG; VON = 0 STD 0 MIN 0 SEK, BIS = 23 STD 59 MIN 59 SEK] |
| Kalendermonatskarte mit tatsächlicher Gültigkeit bis 03:59:59 Uhr des Folgetags (Betriebstagsende) | Dauer[VON = 1 TAG 0 STD 0 MIN 0 SEK, BIS = MAX TAG 23 STD 59 MIN 59 SEK; BIS.GUELTIG += 4 STD] |
| Gleitende Monatskarte (gültig bis zum gleichen Tag des Folgemonats, falls nicht vorhanden, gültig bis zum letzten Tag des Monats) | Dauer[VON = 0 STD 0 MIN 0 SEK, BIS = 23 STD 59 MIN 59 SEK; BIS += 1 MON; \* BIS != OK: BIS -= 1 TAG] |
| Gleitende Monatskarte (gültig bis zum gleichen Tag minus eins des Folgemonats, falls nicht vorhanden, gültig bis zum letzten Tag des Monats) | Dauer[VON = 0 STD 0 MIN 0 SEK, BIS = 23 STD 59 MIN 59 SEK; BIS += 1 MON; \* BIS != OK: BIS -= 1 TAG | BIS -= 1 TAG] |
| Gleitende Monatskarte (gültig bis zum gleichen Tag des Folgemonats 12:00 Uhr, falls nicht vorhanden, gültig bis zum Folgetag des letzten Tags des Folgemonats 03:59:59 Uhr (Betriebstagsende) mit dem Text "Betriebstagsende") | Dauer[VON = 0 STD 0 MIN 0 SEK, BIS += 1 MON; ? BIS != OK: BIS += 1 MON, BIS = 1 TAG 3 STD 59 MIN 59 SEK, BIS.TEXT = "Betriebstagsende" | BIS = 12 STD 0 MIN 0 SEK] |
| Gleitende Wochenkarte mit der bisherigen ergänzenden Gültigkeitsregel 100 ("Liegt das über die Basisgültigkeitsregel berechnete Gültigkeitsende auf einem Samstag, Sonntag oder einem Feiertag, wird die Gültigkeitsdauer bis zum Betriebstagesende des nächsten echten Wochentages (Mo..Fr), der kein Feiertag ist, verlängert") unter der Annahme, dass ein Feiertag mit der numerischen Kennung 1 für die Tagesart gekennzeichnet ist und der Betriebstag um 03:59:59 Uhr endet | Dauer[VON = 0 STD 0 MIN 0 SEK, BIS += 7 TAG, BIS = 23 STD 59 MIN 59 SEK; \* BIS > 5 WOCHENTAG, BIS == 1 TAGESART: BIS += 1 TAG, BIS = 3 STD 59 MIN 59 SEK] |
| 09:00 Uhr Tageskarte, die am Wochenende ganztägig gültig ist | Dauer[? AKTUELL <= 5 WOCHENTAG: VON = 9 STD 0 MIN 0 SEK | VON = 0 STD 0 MIN 0 SEK; BIS = 23 STD 59 MIN 59 SEK] Gueltig[? AKTUELL <= 5 WOCHENTAG & AKTUELL < 9 STD: UNGUELTIG] |
| Tageskarte, die bis zum Betriebstagsende (03:59:59 Uhr) gültig ist und dafür einen Gültigkeitsendetext besitzt | Dauer[VON = 0 STD 0 MIN 0 SEK; BIS = 23 STD 59 MIN 59 SEK, BIS += 4 STD, BIS.TEXT = "Betriebstagsende"] |
| Gewünschter Gültigkeitszeitraum: 01.09. bis zum 15.09. des Folgejahres. Als Umschalttag soll der 01.06. verwendet werden. | Dauer[? AKTUELL >= 1 TAG 6 MON: VON += 1 JAHR, BIS += 1 JAHR; VON = 1 TAG 9 MON 0 STD 0 MIN 0 SEK, BIS += 1 JAHR, BIS = 15 TAG 9 MON 23 STD 59 MIN 59 SEK] |

Bei der Prüfung der Gültigkeit im Rahmen der Kontrolle wird davon ausgegangen, dass bereits zuvor geprüft wurde, ob der aktuelle Zeitpunkt innerhalb der allgemeinen zeitlichen Gültigkeit (wie sie bei der Ausgabe der Fahrtberechtigung durch den Regeltyp Dauer bestimmt wurde) liegt.

## Syntaxvarianten

Im folgenden sind mögliche Alternativen zur oben beschriebenen Syntax, die zwar eine sehr kompakte Schreibweise ermöglicht, aber dafür ggf. für Ungeübte auf den ersten Blick etwas schwerer lesbar ist, angegeben.

Um einen Eindruck über die Syntaxvarianten zu erhalten, ist eines der für die kompakte Syntax angegebenen Beispiele in den unterschiedlichen Syntaxvariationen aufgeführt.

|  |  |
| --- | --- |
| **Syntax** | **Beispiel** |
| **kompakt** | Dauer[VON = 0 STD 0 MIN 0 SEK, BIS += 1 MON; ? BIS != OK: BIS += 1 MON, BIS = 1 TAG 3 STD 59 MIN 59 SEK, BIS.TEXT = "Betriebstagsende" | BIS = 12 STD 0 MIN 0 SEK] |
| **PASCAL-ähnlich (englisch)** | Dauer[FROM = 0h 0m 0s; UNTIL += 1m; WHILE UNTIL != OK DO BEGIN UNTIL += 1m; UNTIL = 1d 3h 59m 59s; UNTIL.TEXT = "Betriebstagsende" END ELSE UNTIL = 12h 0m 0s] |
| **PASCAL-ähnlich (deutsch)** | Dauer[VON = 0 STD 0 MIN 0 SEK; BIS += 1 MON; SOLANGE BIS != OK WIEDERHOLE BEGINNE BIS += 1 MON; BIS = 1 TAG 3 STD 59 MIN 59 SEK; BIS.TEXT = "Betriebstagsende" ENDE SONST BIS = 12 STD 0 MIN 0 SEK] |

## Tagesart-/Betriebstagstabelle

Um bei Zeiträumen, deren Tage alle die gleiche Tagesart besitzen (z.B. bei Sommerferien), nicht für jeden einzelnen Tag einen Eintrag in der Tagesart-/Betriebstagstabelle zu haben, kennzeichnet ein negativer Wert bei einer Tagesart, dass diese Tagesart ab dem angegebenen Tag bis zum chronologisch nächsten, in der Tagesart-/Betriebstagstabelle vorhandenen Tag gilt.

### Beispiel

Für den Fall, dass der Zeitraum 1.6.2020 bis einschließlich 31.08.2020 mit der Tagesart 2 und alle anderen Tage mit der Tagesart 1 gekennzeichnet sein sollen, sind die folgenden Einträge in der Tagesart-/Betriebstagstabelle erforderlich:

|  |  |
| --- | --- |
| **Datum** | **Tagesart** |
| 1.1.2020 | 1 |
| 1.6.2020 | -2 |
| 1.9.2020 | 1 |